home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 008 / ibmsong.bas (.txt) < prev    next >
Encoding:
GW-BASIC  |  1984-04-24  |  4.9 KB  |  141 lines
  1. 4  WIDTH 80
  2. 5  ON ERROR GOTO 9500
  3. 6  PLAY ("P64")
  4. 10  GOSUB 9000
  5. 30  B$=CHR$(2)
  6. 40  DIM N$(165)
  7. 50  DIM L$(15)
  8. 60  DIM B%(253)
  9. 70  X% = 165
  10. 80  FOR I% = 1 TO X%
  11. 90  READ N$(I%)
  12. 100  NEXT I%
  13. 110  RESTORE 790
  14. 120  FOR I% = 1 TO 15
  15. 130  READ L$(I%)
  16. 140  NEXT I%
  17. 150  RESTORE 960
  18. 160  FOR I% = 1 TO 253
  19. 170  READ B%(I%)
  20. 180  NEXT I%
  21. 181  PRINT "(Press any key to begin.)";
  22. 183  IF INKEY$ = "" THEN 183
  23. 190  CLS
  24. 200  FOR I% = 1 TO 9
  25. 210  PRINT : PRINT L$(I%)
  26. 220  NEXT I%
  27. 230  R% = 1
  28. 240  S% = 1
  29. 250  B1% = 0
  30. 260  FOR I% = S% TO 165
  31. 270  C% = B%(I%+B1%)
  32. 280  IF C% > 0 THEN GOTO 310
  33. 290  C% = -C%
  34. 300  R% = R% + 2
  35. 310  LOCATE R%,C%
  36. 320  PRINT B$
  37. 330  PLAY N$(I%)
  38. 340  LOCATE  R%,C%
  39. 350  PRINT " "
  40. 360  NEXT I%
  41. 370  IF B1% = 0 THEN 380
  42. 371  LOCATE 21,1
  43. 372  PRINT "Transcription of music and lyrics from a copy of a copy... of 'Ever Onward,'"
  44. 373  PRINT "and program written by Alden B. Johnson."
  45. 374  END
  46. 380  B1% = 88
  47. 390  S% = 78
  48. 400  CLS
  49. 410  COLOR 0,7
  50. 420  LOCATE 1,30
  51. 430  PRINT "Second Chorus"
  52. 440  COLOR 7,0
  53. 450  LOCATE 3,1
  54. 460  FOR I% = 10 TO 15
  55. 470  PRINT L$(I%)
  56. 480  PRINT
  57. 490  NEXT I%
  58. 500  R% = 2
  59. 510  GOTO 260
  60. 520  END
  61. 530  DATA MF T170 L8 MN O3 B4,B8,O4 D4,D8,O3 G4,G8,B4,B8,E4,E8,E4,E8
  62. 540  DATA ML E4.E4 MN P64,E8,F#4,E8,D4,E8,F#4,G8,A4,A#8,ML B4.B4.B4. MN P64
  63. 550  DATA D4.,B4,B8,O4 D4,D8,O3 G4,G8,B4,B8,E4,E8,E4,E8,ML E4.E4 MN P64
  64. 570  DATA F8,F#4,E8,D4,E8,F#4,G8,A4,B8,ML G4.P64,G4.P64,G4.G4 P64 MN,G8
  65. 590  DATA F#4,F#8,A4,A8,O4 D4,D8,O3 A4,A8,F#4,F#8,A4,A8,ML O4 D4.D4 P64 MN,D8
  66. 610  DATA D4,D8,D4,D8,D4,D8,D4,D8,D4,C8,O3 A4,F#8,D4.
  67. 630  DATA O3 D4.,E4.,F#4.,G4.,F#4.,G4.,G#4.,A4.,G4,A8,B4,G8
  68. 650  DATA A4,B8,A4,G8,E4.,ML E4.E4 P64 MN,E8,D#4,E8,G4,F#8,F#4,F8
  69. 670  DATA F#4.,F4,F#8,A4,G8,G4,F#8,G4.,F#4,G8,B4,A8,A4,G#8
  70. 690  DATA A4,E8,F#4,G8,A4.,ML A4.A4 P64 MN,D8,C#4,D8,G4.,G4.
  71. 710  DATA ML G4.G4 P64 MN,D8,E4.,F4.,ML G4.G4 P64 MN,G#8,A4,A8,A4,B8
  72. 730  DATA O4 C#4,C#8,O3 B4,A8,O4 ML D4.D4.D4 P64 MN,C8,O3 A4,F#8,D4.,E4.,F#4.,G4.
  73. 750  DATA F#4,F#8,G4,G8,G#4,G#8,A8,G#8,A8,B4,O4 C8,D4,E8,O3 B4.,A4.
  74. 770  DATA ML G4.G4.G4 MN
  75. 790  DATA"There's a feel-ing ev'ry where of big-ger things in store. Of new hor-i-zons"
  76. 800  DATA"com-ing in-to view. Our aim is clear: To make each year ex-ceed the one be-fore"
  77. 810  DATA"Stay-ing in the lead in ev'ry-thing we do. The will to win is built right in."
  78. 820  DATA"It will not be de-nied. And we will go a-head we know by work-ing side by side."
  79. 830  DATA"Ev-er On-ward, Ev-er On-ward That's the spir-it that has brought us fame."
  80. 840  DATA"We're big but big-ger we will be. We can't fail for all can see that to serve"
  81. 850  DATA"hu-man-i-ty has been our aim; Our pro-ducts now are known in ev'ry zone."
  82. 860  DATA"Our rep-u-ta-tion spark-les like a gem, We've fought our way thru and new"
  83. 870  DATA"Fields we're sure to con-quer too for the Ev-er On-ward  I B M"
  84. 880  DATA"Ev-er On-ward, Ev-er On-ward We're bound for the top to nev-er fall."
  85. 890  DATA"Right here and now we thank-ful-ly pledge sin-cer-est loy-al-ty to the"
  86. 900  DATA"cor-por-a-tion that's the best of all. Our lead-ers we re-vere,"
  87. 910  DATA"and while we're here, Let's show the world just what we think of them!"
  88. 920  DATA"So let us sing men, sing men, once or twice then sing a-gain for the"
  89. 930  DATA"                              Ev-er On-ward  I B M"
  90. 960  DATA 3,9,12,17,21,23,28,32,36,39,45,50,55,60,64,68,71,74
  91. 980  DATA -2,6,9,12,17,22,26,29,34,39,43,48,53,57,61,66,70,73,78
  92. 1000  DATA -2,3,7,10,14,18,22,26,28,32,37,40,45,49,53,57,60,65,71,75
  93. 1020  DATA -1,6,10,13,16,20,26,29,33,37,40,43,47,51,55,59,64,68,72,77
  94. 1040  DATA -1,4,7,11,16,19,22,26,32,38,43,46,50,55,61,66,70,70
  95. 1060  DATA -3,8,12,16,20,23,27,31,35,40,45,50,54,58,62,66,70,75
  96. 1080  DATA -1,5,8,10,14,18,23,27,27,32,36,40,46,50,55,59,63,65,70
  97. 1100  DATA -2,6,9,11,15,21,26,30,34,37,43,49,55,59,63,68,72
  98. 1120  DATA -3,10,15,19,23,27,32,36,40,44,46,49,53,58,60,62
  99. 1140  DATA 1,4,7,11,16,19,22,26,32,38,43,47,51,54,58,61,66,66
  100. 1160  DATA -3,8,13,17,20,25,30,33,38,44,48,52,56,59,62,65,69
  101. 1180  DATA -2,6,9,12,18,24,28,32,36,36,41,46,50,53,56,60
  102. 1200  DATA -2,7,13,18,24,30,35,40,45,50,54,59,63,68
  103. 1220  DATA -1,5,8,12,17,22,27,32,36,41,46,51,55,58,63,67
  104. 1240  DATA -31,34,37,41,46,48,50
  105. 1250  END
  106. 9000  COLOR 7,0
  107. 9010  KEY OFF
  108. 9020  CLS
  109. 9030  DIM H$(9)
  110. 9040  H$(1)="In the legend of IBM, there are tales of a ritual frequently performed"
  111. 9050  H$(2)="long, long ago in sales meetings, far, far away.  This ritual involved"
  112. 9060  H$(3)="young salesmen and centered around a small book of chants, or songs.  It is"
  113. 9070  H$(4)="said that these songs were a source of great inspiration to the salesforce"
  114. 9080  H$(5)="as it prepared to go out into the world. Although this ritual is no longer"
  115. 9090  H$(6)="practiced, one of the songs has nevertheless survived, being copied and"
  116. 9100  H$(7)="passed down through generation after generation of IBMers."
  117. 9110  H$(8)="The IBM Philharmonic Computer presents:"
  118. 9120  FOR I% = 1 TO 8
  119. 9130  PRINT H$(I%)
  120. 9140  NEXT I%
  121. 9150  COLOR 0,7
  122. 9160  LOCATE 9,25
  123. 9170  PRINT CHR$(201);:FOR I% = 1 TO 30:PRINT CHR$(205);:NEXT I%:PRINT CHR$(187)
  124. 9180  L$ = CHR$(186)
  125. 9190  L1$ = L$ + SPACE$(30) + L$
  126. 9200  LOCATE 10,25:PRINT L$+"       IBM Rally Song         "+L$
  127. 9210  LOCATE 11,25:PRINT L1$
  128. 9220  LOCATE 12,25:PRINT L$+"         ";
  129. 9230  COLOR 15,0:PRINT"EVER ONWARD";:COLOR 0,7
  130. 9240  PRINT "          "+L$
  131. 9250  FOR I% = 13 TO 20: LOCATE I%,25: PRINT L1$: NEXT I%
  132. 9260  LOCATE 21,25:PRINT L$+"    Written especially for    "+L$
  133. 9270  LOCATE 22,25:PRINT L$+"       IBM Corporation        "+L$
  134. 9280  LOCATE 23,25
  135. 9290  PRINT CHR$(200);:FOR I% = 1 TO 30:PRINT CHR$(205);:NEXT I%:PRINT CHR$(188)
  136. 9300  COLOR 7,0
  137. 9340  RETURN
  138. 9500  CLS
  139. 9510  PRINT "This program requires ADVANCED BASIC; Please reload, using BASICA"
  140. 9520  END
  141.